Using in your project

There are many ways to add libbase to your project. It is up to you to decide which one suits your needs the best. Below you will find a recommended (and probably the easiest) way to do so.

Recommended way (CMake + vcpkg)

This is a step-by-step guide to create a new project that uses libbase library using Git, CMake and vcpkg. If you wish to add libbase to your existing project, please skip here.

1. Create a new Git repository and add initial files.

   $ git init
   $ git add [...]
   $ git commit -m "Initial commit"
   

2. Create a new CMake script and a simple C++ source file.

   CMakeLists.txt

   cmake_minimum_required(VERSION 3.13)
   project(project-name VERSION 1.0 LANGUAGES CXX)
   
   add_executable(project-name "")
   
   target_sources(project-name
     PRIVATE
       src/main.cc
   )
   

   src/main.cc

   #include <iostream>
   
   int main() {
     std::cout << "Hello World!" << std::endl;
     return 0;
   }
   

3. Initialize vcpkg and add libbase library as a dependency

   Important

   To avoid name clashes with other libraries, the vcpkg port for this library is called ripper37-libbase. This is the name you should use when adding it to your project.

   $ vcpkg new --application
   $ vcpkg add port ripper37-libbase
   

   Note

   You can customize which parts of libbase you want to use by specifying which features you want to enable. To do that, you need to modify the dependency entry in the vcpkg.json file to look like:

   vcpkg.json

   {
     "dependencies": [
       // ...
       {
         "name": "ripper37-libbase",
         "default-features": false,
         "features": [
           // list features that you need here
         ]
       },
       // ...
     ]
   }
   

   Currently available features are:

   • net - enables networking module (enabled by default)

   • win - enables WinAPI integration module

   • wx - enables wxWidgets integration module

4. Add libbase dependency and link with it in your CMake script.

   CMakeLists.txt

   cmake_minimum_required(VERSION 3.13)
   project(project-name VERSION 1.0 LANGUAGES CXX)
   
   find_package(libbase CONFIG REQUIRED)
   
   add_executable(project-name "")
   target_link_libraries(project-name PRIVATE libbase::libbase)
   target_sources(project-name
     PRIVATE
       src/main.cc
   )
   

   If you want to use optional modules, you need to add corresponding component names to the find_package() function call and link with their targets in target_link_libraries().

   Available components and their target names

   Module	Component	Target
   Networking module	net	libbase::libbase_net
   WinAPI integration module	win	libbase::libbase_win
   wxWidgets integration module	wx	libbase::libbase_wx

5. Use libbase library in your project.

   src/main.cc

   #include <iostream>
   
   #include "base/callback.h"
   
   int main() {
     base::BindOnce([]() { std::cout << "Hello World!" << std::endl; }).Run();
     return 0;
   }
   

6. Compile, build and run!

   $ export VCPKG_ROOT=/path/to/vcpkg
   $ cmake -S . -b build
   $ cmake --build build
   $ ./build/project-name
   Hello World!
   

Tip

More advanced example project using this method can be viewed here: RippeR37/libbase-example-vcpkg.

Alternative ways

If you don’t want to use vcpkg to resolve dependencies, you can replace step 3 and not export VCPKG_ROOT environment variable and use one of these methods instead:

• Manually build and install libbase and all of its dependencies in your system. For more details on how to do that, please refer to the building page.

• Use CMake’s FetchContent module to download and build libbase as part of your project. To do this, add below snippet to your CMake script:

  CMakeLists.txt

  include(FetchContent)
  FetchContent_Declare(
      libbase
      GIT_REPOSITORY https://github.com/ripper37/libbase.git
      GIT_TAG        <commit_or_tag_to_fetch>
  )
  FetchContent_MakeAvailable(libbase)
  

  Caution

  This doesn’t auto-resolve libbase required dependencies by itself. You will still need to build and install them manually or use FetchContent to declare and make them available in your CMake project before including the libbase library.

  Tip

  Simple example project using this method can be viewed here: RippeR37/libbase-example-fetchcontent.

• Use CMake’s add_subdirectory() to add libbase to your project whil will work similarly to the above FetchContent method. To get libbase source files you can download them or add libbase as a Git submodule.

  Terminal

  $ git submodule add https://github.com/RippeR37/libbase
  $ git submodule update --init
  

  CMakeLists.txt

  add_subdirectory(libbase)
  

  Caution

  Similarly to the FetchContent method, this also doesn’t resolve libbase dependencies by itself. Furthermore, this type of dependency management is not recommended by many - please consider alternatives before choosing it.

  Tip

  Simple example project using this method can be viewed here: RippeR37/libbase-example-submodules.